快捷搜索:  as

89c51单片机动态扫描接口设计

什么叫动态扫描显示

单片机系统中动态扫描显示 接口是单片机中利用最为广泛的一种显示要领之一。其接口 电路 是把所有显示器的8个笔划段a-h同名端连在一路,而每一个显示器的公共极COM是各自自力地受I/O线节制。CPU向字段输出口送出字形码时,所有显示器接管到相同的字形码,但究竟是那个显示器亮,则取决于COM端,而这一端是由I/O节制的,以是我们就能自行抉择何时显示哪一位了。而所谓动态扫描便是指我们采纳分时的法子,轮流节制各个显示器的COM端,使各个显示器轮流点亮。

在轮流点亮扫描历程中,每位显示器的点亮光阴是极为短暂的(约1ms),但因为人的视觉暂留征象及发光 二极管 的余辉效应,只管实际上各位显示器并非同时点亮,但只要扫描的速率足够快,给人的印象便是一组稳定的显示数据,不会有闪烁感。

由 89c51 的P0口能注意灌输较大年夜的电流,以是我们采纳共阳的 数码管 ,并且不用限流 电阻 ,而只是用两只 1N4004 进行降压后给数码管供电,这里仅用了两只,实际上还能扩充。它们的公共端则由PNP型 三极管 8550 节制,显然,假如8550导通,则对应的数码管就能亮,而假如8550截止,则对应的数码管就弗成能亮,8550是由P2.7,P2.6节制的。这样我们就能经由过程节制P27、P26达到节制某个数码管亮或灭的目的。

下面的这个单片机法度榜样,便是用 实验板 上的数码管显示0和1。

FIRST EQU P2.7 ;第一位数码管的位节制

SECOND EQU P2.6 ;第二位数码管的位节制

DISPBUFF EQU 5AH ;显示缓冲区为5AH和5BH

ORG 0000H

AJMP START

ORG 30H

START:

MOV SP,#5FH ;设置客栈

MOV P1,#0FFH

MOV P0,#0FFH

MOV P2,#0FFH ;初始化,所显示器, LED

MOV DISPBUFF,#0 ;第一位显示0

MOV DISPBUFF+1,#1 ;第二握显示1

LOOP:

LCALL DISP ;调用显示法度榜样

AJMP LOOP

;主法度榜样到此停止

DISP:

PUSH ACC ;ACC入栈

PUSH PSW ;PSW入栈

MOV A,DISPBUFF ;取第一个待显示数

MOV DPTR,#DISPTAB ;字形表首地址

MOVC A,@A+DPTR ;取字形码

MOV P0,A ;将字形码送P0位(段口)

CLR FIRST ;开第一位显示器位口

LCALL DELAY ;延时1毫秒

SETB FIRST ;关闭第一位显示器(开始筹备第二位的数据)

MOV A,DISPBUFF+1 ;取显示缓冲区的第二位

MOV DPTR,#DISPTAB

MOVC A,@A+DPTR

MOV P0,A ;将第二个字形码送P0口

CLR SECOND ;开第二位显示器

LCALL DELAY ;延时

SETB SECOND ;关第二位显示

POP PSW

POP ACC

RET

DELAY: ;延时1毫秒

PUSH PSW

SETB RS0

MOV R7,#50

D1: MOV R6,#10

D2: DJNZ R6,$

DJNZ R7,D1

POP PSW

RET

DISPTAB:DB 28H,7EH,0a4H,64H,72H,61H,21H,7CH,20H,60H

END

从上面的单片机例程中能看出,动态扫描显示必须由CPU持续地调用显示法度榜样,才能包管持续持续的显示。

上面的这个法度榜样能实现数字的显示,但不太实用,为什么呢?这里仅是显示两个数字,并没有做其他的事情,是以,两个数码管轮流显示1毫秒,没有问题,实际的事情中,当然弗成能只显示两个数字,照样要做其他的工作的,这样在二次调用显示法度榜样之间的光阴距离就不一不定了,假如光阴距离对照长,就会使显示不继续。而实际事情中是很难包管所有事情都能在很短光阴内完成的。况且这个显示法度榜样也有点“挥霍”,每个数码管显示都要占用1个毫秒的光阴,这在很多合是不容许的,怎么办呢?我们能借助于 准时器 ,准韶光阴一到,孕育发生中断,点亮一个数码管,然后顿时返回,这个数码管就会不停亮到下一次准韶光阴到,而不用调用延时法度榜样了,这段光阴能留给主法度榜样干其他的事。到下一次准韶光阴到则显示下一个数码管,这样就很少挥霍了。

Counter EQU 59H ; 计数器 ,显示法度榜样经由过程它得知现正显示哪个数码管

FIRST EQU P2.7 ;第一位数码管的位节制

SECOND EQU P2.6 ;第二位数码管的位节制

DISPBUFF EQU 5AH ;显示缓冲区为5AH和5BH

ORG 0000H

AJMP START

ORG 000BH ;准时器T0的进口

AJMP DISP ;显示法度榜样

ORG 30H

START:

MOV SP,#5FH ;设置客栈

MOV P1,#0FFH

MOV P0,#0FFH

MOV P2,#0FFH ;初始化,所显示器,LED灭

MOV TMOD,#00000001B ;准时器T0事情于模式1(16位准时/计数模式)

MOV TH0,#HIGH(65536- 2000 )

MOV TL0,#LOW(65536-2000)

SETB TR0

SETB EA

SETB ET0

MOV Counter,#0 ;计数器初始化

MOV DISPBUFF,#0 ;第一位始终显示0

MOV A,#0

LOOP:

MOV DISPBUFF+1,A ;第二位轮流显示0-9

INC A

LCALL DELAY

CJNE A,#10,LOOP

MOV A,#0

AJMP LOOP ;在个中心能按排随意率性法度榜样,这里仅作示范。

;主法度榜样到此停止

DISP: ;准时器T0的中断相应法度榜样

PUSH ACC ;ACC入栈

PUSH PSW ;PSW入栈

MOV TH0,#HIGH(65536-2000) ;准韶光阴为2000个周期,约 2170 微秒( 11.0592M )

MOV TL0,#LOW(65536-2000)

SETB FIRST

SETB SECOND ;关显示

MOV A,#DISPBUFF ;显示缓冲区首地址

ADD A,Counter

MOV R0,A

MOV A,@R0 ;根据计数器的值取对应的显示缓冲区的值

MOV DPTR,#DISPTAB ;字形表首地址

MOVC A,@A+DPTR ;取字形码

MOV P0,A ;将字形码送P0位(段口)

MOV A,Counter ;取计数器的值

JZ DISPFIRST ;假如是0则显示第一位

CLR SECOND ;不然显示第二位

AJMP DISPNEXT

DISPFIRST:

CLR FIRST ;显示第一位

DISPNEXT:

INC Counter ;计数器加1

MOV A,Counter

DEC A ;假如计数器计到2,则让它回0

DEC A

JZ RSTCOUNT

AJMP DISPEXIT

RSTCOUNT:

MOV Counter,#0 ;计数器的值只能是0或1

DISPEXIT:

POP PSW

POP ACC

RETI

DELAY: ;延时130毫秒

PUSH PSW

SETB RS0

MOV R7,#255

D1: MOV R6,#255

D2: NOP

NOP

NOP

NOP

DJNZ R6,D2

DJNZ R7,D1

POP PSW

RET

DISPTAB:DB 28H,7EH,0a4H,64H,72H,61H,21H,7CH,20H,60H

END

从上面的单片机法度榜样能看出,动态显示和静态显示比拟,法度榜样稍有点繁杂,不过,这是值得的。这个法度榜样有必然的通用性,只要改变端口的值及计数器的值就能显示更多位数了。

您可能还会对下面的文章感兴趣: